1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
|
;;
;; mur.sat
;;
;; Somewhen in the year 2011, mur.at will have a nano satellite launched
;; into a low earth orbit (310 km above the surface of our planet). The
;; satellite itself is a TubeSat personal satellite kit, developed and
;; launched by interorbital systems. mur.sat is a joint venture of mur.at,
;; ESC im Labor and realraum.
;;
;; Please visit the project hompage at sat.mur.at for further information.
;;
;;
;; Copyright (C) 2011 Christian Pointner <equinox@mur.at>
;;
;; This file is part of mur.sat.
;;
;; mur.sat is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; any later version.
;;
;; mur.sat is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with mur.sat. If not, see <http://www.gnu.org/licenses/>.
;;
;; -------------------------------------
;; PREAMBLE
LIST p=12F635
include "p12f635.inc"
__config _WUREN_OFF & _FCMEN_OFF & _IESO_OFF & _BOD_OFF & _CPD_OFF & _CP_OFF & _MCLRE_OFF & _PWRTE_OFF & _WDT_OFF & _INTRC_OSC_NOCLKOUT
;; -------------------------------------
;; DEFINES
;; constants
DOT EQU .256 - .29
DASH EQU .256 - .87
ESPACE EQU .256 - .29
CSPACE EQU .256 - .87
WSPACE EQU .256 - .203
ENABLE_TIME EQU .256 - .10
BEACON_INT EQU .10 ; *2 = Beacon Interval in seconds
;; I/O Pins
CWENABLE EQU GP0
CWOUT EQU GP1
SCLK EQU GP2
SDAT EQU GP4
;; variables
;; page 0 only
ELEMENT EQU H'0040'
ELECNT EQU H'0041'
CHAR EQU H'0042'
PARITY EQU H'0043'
CHARCNT EQU H'0044'
PENTLE0 EQU H'0045'
PENTLE1 EQU H'0046'
PENTLECNT EQU H'0047'
BUF EQU H'0050'
;; all pages
BEACONCNTH EQU H'007C'
BEACONCNTL EQU H'007B'
SECCNT EQU H'007D'
W_TEMP EQU H'007E'
STATUS_TEMP EQU H'007F'
;; -------------------------------------
;; Reset Vector
org .0
goto init
;; -------------------------------------
;; Interrupt Vector
org .4
;; save context
movwf W_TEMP
swapf STATUS,W
movwf STATUS_TEMP
bcf STATUS,RP0
bcf STATUS,RP1
btfsc PIR1,TMR1IF
goto tmr1_int
ext_int
;; TODO: read bit from GPIO,SDAT and add to received string
goto interrupt_end
tmr1_int
bcf PIR1,TMR1IF
movf SECCNT,w
btfss STATUS,Z
decf SECCNT,f
interrupt_end
;; restore context
swapf STATUS_TEMP,W
movwf STATUS
swapf W_TEMP,F
swapf W_TEMP,W
retfie
;; -------------------------------------
;; INIT
init
;; bank 1
bsf STATUS,RP0
bcf STATUS,RP1
movlw b'10000011'
movwf OPTION_REG
movlw b'11111100'
movwf TRISIO
movlw b'00000001'
movwf PIE1
movlw b'00000000'
movwf OSCCON
bcf STATUS,RP0
;; bank 0
clrf TMR1L
clrf TMR1H
movlw b'00000111'
movwf T1CON
movlw b'01000000' ; enable external interrupt bit4
movwf INTCON
movlw b'00000111'
movwf CMCON0
bcf GPIO,CWOUT
bcf GPIO,CWENABLE
movlw BEACON_INT
movwf SECCNT
clrf BEACONCNTL ; TODO: read Beaconcnt from EEPROM
clrf BEACONCNTH
bsf INTCON,GIE
goto main
;; -------------------------------------
;; TABLES
;; Morse Codes: 0=dot, 1=dash
getcw
addwf PCL,f
nop
retlw b'00010000' ; !
retlw b'01001000' ; "
retlw b'00000000' ; #
retlw b'00010010' ; $
retlw b'00000000' ; %
retlw b'01000000' ; &
retlw b'01111000' ; '
retlw b'10110000' ; (
retlw b'10110100' ; )
retlw b'00000000' ; *
retlw b'01010000' ; +
retlw b'11001100' ; ,
retlw b'10000100' ; -
retlw b'01010100' ; .
retlw b'10010000' ; /
retlw b'11111000' ; 0
retlw b'01111000' ; 1
retlw b'00111000' ; 2
retlw b'00011000' ; 3
retlw b'00001000' ; 4
retlw b'00000000' ; 5
retlw b'10000000' ; 6
retlw b'11000000' ; 7
retlw b'11100000' ; 8
retlw b'11110000' ; 9
retlw b'11100000' ; :
retlw b'10101000' ; ;
retlw b'00010100' ; <
retlw b'10001000' ; =
retlw b'10001010' ; >
retlw b'00110000' ; ?
retlw b'01000000' ; @
retlw b'01000000' ; A
retlw b'10000000' ; B
retlw b'10100000' ; C
retlw b'10000000' ; D
retlw b'00000000' ; E
retlw b'00100000' ; F
retlw b'11000000' ; G
retlw b'00000000' ; H
retlw b'00000000' ; I
retlw b'01110000' ; J
retlw b'10100000' ; K
retlw b'01000000' ; L
retlw b'11000000' ; M
retlw b'10000000' ; N
retlw b'11100000' ; O
retlw b'01100000' ; P
retlw b'11010000' ; Q
retlw b'01000000' ; R
retlw b'00000000' ; S
retlw b'10000000' ; T
retlw b'00100000' ; U
retlw b'00010000' ; V
retlw b'01100000' ; W
retlw b'10010000' ; X
retlw b'10110000' ; Y
retlw b'11000000' ; Z
;; Morse Code Length
getcwlen
addwf PCL,f
nop
retlw .5 ; !
retlw .6 ; "
retlw .0 ; #
retlw .7 ; $
retlw .0 ; %
retlw .5 ; &
retlw .6 ; '
retlw .5 ; (
retlw .6 ; )
retlw .0 ; *
retlw .5 ; +
retlw .6 ; ,
retlw .6 ; -
retlw .6 ; .
retlw .5 ; /
retlw .5 ; 0
retlw .5 ; 1
retlw .5 ; 2
retlw .5 ; 3
retlw .5 ; 4
retlw .5 ; 5
retlw .5 ; 6
retlw .5 ; 7
retlw .5 ; 8
retlw .5 ; 9
retlw .6 ; :
retlw .6 ; ;
retlw .6 ; <
retlw .5 ; =
retlw .7 ; >
retlw .6 ; ?
retlw .6 ; @
retlw .2 ; A
retlw .4 ; B
retlw .4 ; C
retlw .3 ; D
retlw .1 ; E
retlw .4 ; F
retlw .3 ; G
retlw .4 ; H
retlw .2 ; I
retlw .4 ; J
retlw .3 ; K
retlw .4 ; L
retlw .2 ; M
retlw .2 ; N
retlw .3 ; O
retlw .4 ; P
retlw .4 ; Q
retlw .3 ; R
retlw .3 ; S
retlw .1 ; T
retlw .3 ; U
retlw .4 ; V
retlw .3 ; W
retlw .4 ; X
retlw .4 ; Y
retlw .4 ; Z
;; Base32 Code
base32
addwf PCL,f
retlw 'A' - ' '
retlw 'B' - ' '
retlw 'C' - ' '
retlw 'D' - ' '
retlw 'E' - ' '
retlw 'F' - ' '
retlw 'G' - ' '
retlw 'H' - ' '
retlw 'I' - ' '
retlw 'J' - ' '
retlw 'K' - ' '
retlw 'L' - ' '
retlw 'M' - ' '
retlw 'N' - ' '
retlw 'O' - ' '
retlw 'P' - ' '
retlw 'Q' - ' '
retlw 'R' - ' '
retlw 'S' - ' '
retlw 'T' - ' '
retlw 'U' - ' '
retlw 'V' - ' '
retlw 'W' - ' '
retlw 'X' - ' '
retlw 'Y' - ' '
retlw 'Z' - ' '
retlw '2' - ' '
retlw '3' - ' '
retlw '4' - ' '
retlw '5' - ' '
retlw '6' - ' '
retlw '7' - ' '
;; fixed strings
callsign
addwf PCL,f
nop
retlw 'R' - ' '
retlw 'U' - ' '
retlw 'M' - ' '
retlw '6' - ' '
retlw 'E' - ' '
retlw 'O' - ' '
;; -------------------------------------
;; SUBROUTINES
dottime
movwf TMR0
bcf INTCON,T0IF
dot_inner
btfss INTCON,T0IF
goto dot_inner
return
;; -------------------------------------
send_char
movwf CHAR
call getcw
movwf ELEMENT
movf CHAR,w
call getcwlen
movwf ELECNT
movf ELECNT,f
btfsc STATUS,Z
return
movf CHAR,w
xorwf PARITY,f
char_next_element
bsf GPIO,CWOUT
btfss ELEMENT,7
movlw DOT
btfsc ELEMENT,7
movlw DASH
call dottime
bcf GPIO,CWOUT
rlf ELEMENT,f
decfsz ELECNT,f
goto char_espace
return
char_espace
movlw ESPACE
call dottime
goto char_next_element
;; -------------------------------------
send_callsign
movlw .6
movwf CHARCNT
callsign_next_char
call callsign
call send_char
decfsz CHARCNT,f
goto callsign_cspace
return
callsign_cspace
movlw CSPACE
call dottime
movf CHARCNT,w
goto callsign_next_char
;; -------------------------------------
send_base32
movwf PENTLECNT
case0
rrf INDF,w
movwf PENTLE0
rrf PENTLE0,f
rrf PENTLE0,w
andlw b'00011111'
call base32
call send_char
decfsz PENTLECNT,f
goto case1
return
case1
movlw CSPACE
call dottime
rlf INDF,w
movwf PENTLE0
rlf PENTLE0,w
andlw b'00011100'
movwf PENTLE0
incf FSR,f
swapf INDF,w
movwf PENTLE1
rrf PENTLE1,f
rrf PENTLE1,w
andlw b'00000011'
iorwf PENTLE0,w
call base32
call send_char
decfsz PENTLECNT,f
goto case2
return
case2
movlw CSPACE
call dottime
rrf INDF,w
andlw b'00011111'
call base32
call send_char
decfsz PENTLECNT,f
goto case3
return
case3
movlw CSPACE
call dottime
swapf INDF,w
andlw b'00010000'
movwf PENTLE0
incf FSR,f
swapf INDF,w
andlw b'00001111'
iorwf PENTLE0,w
call base32
call send_char
decfsz PENTLECNT,f
goto case4
return
case4
movlw CSPACE
call dottime
rlf INDF,w
andlw b'00011110'
movwf PENTLE0
incf FSR,f
btfsc INDF,7
bsf PENTLE0,0
movf PENTLE0,w
call base32
call send_char
decfsz PENTLECNT,f
goto case5
return
case5
movlw CSPACE
call dottime
rrf INDF,w
movwf PENTLE0
rrf PENTLE0,w
andlw b'00011111'
call base32
call send_char
decfsz PENTLECNT,f
goto case6
return
case6
movlw CSPACE
call dottime
swapf INDF,w
movwf PENTLE0
rrf PENTLE0,w
andlw b'00011000'
movwf PENTLE0
incf FSR,f
swapf INDF,w
movwf PENTLE1
rrf PENTLE1,w
andlw b'00000111'
iorwf PENTLE0,w
call base32
call send_char
decfsz PENTLECNT,f
goto case7
return
case7
movlw CSPACE
call dottime
movf INDF,w
andlw b'00011111'
call base32
call send_char
decfsz PENTLECNT,f
goto caseend
return
caseend
movlw CSPACE
call dottime
incf FSR,f
goto case0
;; -------------------------------------
send_parity
movf PARITY,w
btfsc PARITY,5
xorlw b'00000001'
andlw b'00011111'
call base32
call send_char
return
;; -------------------------------------
send_beacon
bsf GPIO,CWENABLE
movlw ENABLE_TIME
call dottime
clrf PARITY
;; CALLSIGN
call send_callsign
;; -------
movlw WSPACE
call dottime
;; BEACON CNT
movlw BEACONCNTH
movwf FSR
movlw .3
call send_base32
;; -------
movlw WSPACE
call dottime
;; PARITY
call send_parity
incfsz BEACONCNTL,f
goto beacon_end
incf BEACONCNTH,f
;; TODO write new cnt value to EEPROM
beacon_end
bcf GPIO,CWENABLE
return
;; -------------------------------------
;; MAINLOOP
main
;; this gets called after reset and whenever a wakeup occured
;; (after TMR1 overrun or interrupt on GP2)
movf SECCNT,f
btfss STATUS,Z
goto powerdown
;; this gets called every 2*BEACON_INT seconds
movlw BEACON_INT
movwf SECCNT
call send_beacon
powerdown
sleep
nop
goto main
;; -------------------------------------
;; END
end
|
