1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
|
;;
;; mur.sat
;;
;; Somewhen in the year 2012, mur.at will have a nano satellite launched
;; into a low earth orbit (310 km above the surface of our planet). The
;; satellite itself is a TubeSat personal satellite kit, developed and
;; launched by interorbital systems. mur.sat is a joint venture of mur.at,
;; ESC im Labor and realraum.
;;
;; Please visit the project hompage at sat.mur.at for further information.
;;
;;
;; Copyright (C) 2011-2013 Christian Pointner <equinox@mur.at>
;;
;; This file is part of mur.sat.
;;
;; mur.sat is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; any later version.
;;
;; mur.sat is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with mur.sat. If not, see <http://www.gnu.org/licenses/>.
;;
;; -------------------------------------
;; PREAMBLE
LIST p=16F887
include "p16f887.inc"
;; This is specified via bootloader-IHU.asm
;; __config _CONFIG1, _DEBUG_OFF & _LVP_OFF & _FCMEN_OFF & _IESO_OFF & _BOR_NSLEEP & _CPD_OFF & _CP_OFF & _MCLRE_OFF & _PWRTE_ON & _WDT_OFF & _XT_OSC
;; __config _CONFIG2, _BOR21V & _WRT_OFF
BOOTLOADER EQU H'003'
USERVECT EQU H'100'
ISRVECT EQU H'104'
;; -------------------------------------
;; DEFINES
;; constants
;; I/O Pins
;; PortA
#define SOLAR_C0 PORTA,0
#define SOLAR_C1 PORTA,1
#define SOLAR_C2 PORTA,2
#define VREF PORTA,3
#define OWIRE PORTA,4
#define OW_TEMP PORTA,5
;#define OSC2 PORTA,6
;#define OSC1 PORTA,7
;; PortB
#define CTR_INT PORTB,0
#define POWER_FAIL PORTB,1
#define CAPGOOD PORTB,2
#define BAT_INT PORTB,3
#define DEPLOY PORTB,4
#define RTC_RST PORTB,5
;#define PGC PORTB,6
;#define PGD PORTB,7
;; PortC
#define MPU_RST PORTC,0
#define CTR_RST PORTC,1
#define BAT_RST PORTC,2
#define SPI_SCK PORTC,3
#define SPI_MISO PORTC,4
#define SPI_MOSI PORTC,5
#define MPU_TX PORTC,6
#define MPU_RX PORTC,7
;; PortD
#define I2C_SCL PORTD,0
#define I2C_SDA PORTD,1
I2C_PORT EQU PORTD
I2C_MASK EQU b'00000011'
I2C_SDA_MASK EQU b'00000010'
#define CTR_SS PORTD,2
#define BAT_SS PORTD,3
#define MPU_EN PORTD,4
#define HEAT_EN PORTD,5
#define RADIO_SILENCE PORTD,6
#define MAIN_OFF PORTD,7
;; PortE
#define SOLAR_V0 PORTE,0
#define SOLAR_V1 PORTE,1
#define SOLAR_V2 PORTE,2
;; variables
;; page 0 only
TMP EQU H'0020'
WAIT_CNT EQU H'002F'
RTC_BYTE_CNT EQU H'0028'
RTC_TOD0 EQU H'003A'
RTC_TOD1 EQU H'003B'
RTC_TOD2 EQU H'003C'
RTC_TOD3 EQU H'003D'
BUF EQU H'0040'
BUF_END EQU H'004F'
;; all pages
I2C_BYTE EQU H'0070'
I2C_BIT_CNT EQU H'0071'
OWIRE_BYTE EQU H'0072'
OWIRE_BIT_CNT EQU H'0073'
OWIRE_CNT EQU H'0074'
FSR_TEMP EQU H'007D'
W_TEMP EQU H'007E'
STATUS_TEMP EQU H'007F'
;; bits
;; -------------------------------------
;; Reset Vector
org USERVECT ; end of bootloader
goto init
;; -------------------------------------
;; Interrupt Vector
org ISRVECT ; replocated ISR vector
;; save context
movwf W_TEMP
swapf STATUS,W
movwf STATUS_TEMP
movf FSR,w
movwf FSR_TEMP
bcf STATUS,RP0
bcf STATUS,RP1
;; dispatch interrupt sources
btfsc INTCON,INTF
goto int_ctr
btfsc INTCON,RBIF
goto int_portchange
btfsc PIR1,RCIF
goto int_uart_rx
goto interrupt_end
int_ctr
;; TODO: get byte from CTR (via SPI)
bcf INTCON,INTF
goto interrupt_end
int_portchange
btfsc RTC_RST
call rtc_init
btfsc BAT_INT
goto int_bat
bcf INTCON,RBIF
goto interrupt_end
int_bat
;; TODO: get byte from BAT (via SPI)
bcf INTCON,RBIF
goto interrupt_end
int_uart_rx
call uart_rx_byte
btfsc PIR1,RCIF
call uart_rx_byte
btfsc RCSTA,OERR
goto int_uart_rx_oe
goto interrupt_end
int_uart_rx_oe
bcf RCSTA,CREN
bsf RCSTA,CREN
interrupt_end
;; restore context
movf FSR_TEMP,w
movwf FSR
swapf STATUS_TEMP,W
movwf STATUS
swapf W_TEMP,F
swapf W_TEMP,W
retfie
;; -------------------------------------
;; INIT
init
;; bank 3
bsf STATUS,RP0
bsf STATUS,RP1
;; movlw b'00001000' ; TX non-inverted, 16bit Baudrate, no auto baud detect
movlw b'00011000' ; TX inverted, 16bit Baudrate, no auto baud detect
movwf BAUDCTL
movlw b'11101111' ; AN0-AN3,AN5-AN7 as analog
movwf ANSEL ; AN4 as digital
clrf ANSELH ; AN8-AN13 as digital
;; bank 1
bsf STATUS,RP0
bcf STATUS,RP1
movlw b'00111111' ; Weak Pull-UPS for
movwf WPUB ; RTC_RST, DEPLOY, CAPGOOD, POWER_FAIL, BAT_INT, CTR_INT
movlw b'00101000' ; Port Change Interrup on
movwf IOCB ; RTC_RST, BAT_INT
movlw b'00000010' ; Weak-Pull-UPs enabled, INT -> falling edge, TMR0 internal clock
movwf OPTION_REG ; Prescaler @ TMR0, Prescaler 1:8
clrf PSTRCON ; disable pulse steering
movlw b'00010000' ; preselct 125 kHz, clock source as configured by configuration word
movwf OSCCON
;; movlw b'11001111' ; input: RA0-RA3(analog),RA6-RA7(OSC); output: RA4-RA5(1wire)
movlw b'11011111' ; input: RA0-RA3(analog),RA6-RA7(OSC), RA4(BOOTPIN); output: RA5(1wire)
movwf TRISA
movlw b'11111111' ; input: all (interrupts and stats)
movwf TRISB
;; movlw b'11010000' ; input: SPI_MISO,RX,TX; output: (MPU|CTR|BAT)_RST,SPI_(CLK|MOSI)
movlw b'11111111' ; input: all; output: none
movwf TRISC
movlw b'00000011' ; input: I2C_(SDA|SCL); output: (CTR,BAT)_SS, (MPU|HEAT)_EN, RADIO_SILENCE, MAIN_OFF
movwf TRISD
movlw b'11111111' ; intput all (analog)
movwf TRISE
movlw b'00010000' ; result left justified, V_REF_low = 0, V_REF_high = AN3
clrf ADCON1
movlw b'00100100' ; Baudrate = High Speed, async mode, transmit enabled, 8bit
movwf TXSTA
movlw .34 ; Baudrate = 57600 (@ 8MHz) -> -0,79 % Error
;; movlw .51 ; Baudrate = 38400 (@ 8MHz) -> -0,002 % Error
;; movlw .103 ; Baudrate = 19200 (@ 8MHz) -> 0,16 % Error
movwf SPBRG
clrf SPBRGH
movlw b'00100000' ; enable UART RX Interrupt
movwf PIE1
clrf PIE2
;; bank 0
bcf STATUS,RP0
bcf STATUS,RP1
movlw b'01000001' ; CLK = FOSC/8, select AN0, ADC on
movwf ADCON0
movlw b'10010000' ; enable Serial Port, 8bit, enable continues receive, disable address detection
movwf RCSTA
movlw B'01011000' ; enabble Peripherial, INT and Port Change
movwf INTCON
call i2c_init
call spi_init
clrf TMR0
clrf TMP
bsf INTCON,GIE
btfsc RTC_RST ; if RTC is already finished, initialize it!
call rtc_init ; this maybe happend already via interrupt but better save than sorry
goto main
;; -------------------------------------
;; TABLES
include "tables.inc" ; this needs to stay inside 0x100 and 0x200
;; -------------------------------------
;; SUBROUTINES
wait_ms
movwf WAIT_CNT
wait_next
movlw .9
movwf TMR0
bcf INTCON,T0IF
wait_loop
btfss INTCON,T0IF
goto wait_loop
decfsz WAIT_CNT,f
goto wait_next
return
;; -------------------------------------
include "uart.inc"
;; -------------------------------------
include "i2c.inc"
;; -------------------------------------
include "rtc.inc"
;; -------------------------------------
include "spi.inc"
;; -------------------------------------
;; include "temp.inc"
;; -------------------------------------
;; include "adc.inc"
;; -------------------------------------
;; include "solar.inc"
;; -------------------------------------
;; include "math.inc"
;; -------------------------------------
;; MAINLOOP
main
; sleep
; nop
;; --------------------
;; ADC Test
;; call adc_get_solar
;; call solar_calc_power
;; movlw .255
;; call uart_tx_byte
;; movf ADC_SOLAR_C0,w
;; call uart_tx_byte
;; movf ADC_SOLAR_C1,w
;; call uart_tx_byte
;; movf ADC_SOLAR_C2,w
;; call uart_tx_byte
;; movf ADC_SOLAR_V0,w
;; call uart_tx_byte
;; movf ADC_SOLAR_V1,w
;; call uart_tx_byte
;; movf ADC_SOLAR_V2,w
;; call uart_tx_byte
;; movf SOL_POWERH,w
;; call uart_tx_byte
;; movf SOL_POWERL,w
;; call uart_tx_byte
;; goto main
;; --------------------
;; RTC Test program
movf TMP,f
btfsc STATUS,Z
goto main
call rtc_get_time
swapf RTC_TOD3,w
call digit
call uart_tx_byte
movf RTC_TOD3,w
call digit
call uart_tx_byte
swapf RTC_TOD2,w
call digit
call uart_tx_byte
movf RTC_TOD2,w
call digit
call uart_tx_byte
swapf RTC_TOD1,w
call digit
call uart_tx_byte
movf RTC_TOD1,w
call digit
call uart_tx_byte
swapf RTC_TOD0,w
call digit
call uart_tx_byte
movf RTC_TOD0,w
call digit
call uart_tx_byte
movlw '\r'
call uart_tx_byte
movlw '\n'
call uart_tx_byte
clrf TMP
goto main
;; --------------------
;; Temp Test program
;; movf TMP,f
;; btfsc STATUS,Z
;; goto main
;; call temp_read_value
;; swapf OWIRE_BYTE,w
;; call digit
;; call uart_tx_byte
;; movf OWIRE_BYTE,w
;; call digit
;; call uart_tx_byte
;; movlw '\r'
;; call uart_tx_byte
;; movlw '\n'
;; call uart_tx_byte
;; clrf TMP
;; goto main
;; -------------------------------------
;; END
end
|
