1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
|
;;
;; mur.sat
;;
;; Somewhen in the year 2012, mur.at will have a nano satellite launched
;; into a low earth orbit (310 km above the surface of our planet). The
;; satellite itself is a TubeSat personal satellite kit, developed and
;; launched by interorbital systems. mur.sat is a joint venture of mur.at,
;; ESC im Labor and realraum.
;;
;; Please visit the project hompage at sat.mur.at for further information.
;;
;;
;; Copyright (C) 2011-2013 Christian Pointner <equinox@mur.at>
;;
;; This file is part of mur.sat.
;;
;; mur.sat is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; any later version.
;;
;; mur.sat is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with mur.sat. If not, see <http://www.gnu.org/licenses/>.
;;
;; -------------------------------------
i2c_init
movlw ~I2C_MASK ; as every write access is read-update-write this needs
andwf I2C_PORT,f ; to be done in one step (external pull-ups!)
bsf STATUS,RP0
movlw I2C_MASK
iorwf I2C_PORT,f
bcf STATUS,RP0
return
;; -------------------------------------
i2c_start
bsf STATUS,RP0
bcf I2C_SDA
nop
bcf I2C_SCL
bcf STATUS,RP0
return
;; ------------------
i2c_restart
bsf STATUS,RP0
bsf I2C_SDA
nop
bsf I2C_SCL
nop
nop
nop
bcf I2C_SDA
nop
bcf I2C_SCL
bcf STATUS,RP0
return
;; ------------------
i2c_stop
bsf STATUS,RP0
bsf I2C_SCL
nop
bsf I2C_SDA
bcf STATUS,RP0
return
;; ------------------
i2c_send_byte
movwf I2C_BYTE
movlw .8
movwf I2C_BIT_CNT
bsf STATUS,RP0
i2c_send_byte_next
btfss I2C_BYTE,7
bcf I2C_SDA
btfsc I2C_BYTE,7
bsf I2C_SDA
nop
bsf I2C_SCL
nop
nop
bcf I2C_SCL
rlf I2C_BYTE,f
decfsz I2C_BIT_CNT,f
goto i2c_send_byte_next
nop
nop
bsf I2C_SDA
bsf I2C_SCL
bcf STATUS,RP0
movf I2C_PORT,w
bsf STATUS,RP0
bcf I2C_SCL
bcf I2C_SDA
bcf STATUS,RP0
andlw I2C_SDA_MASK
movwf I2C_BYTE
swapf I2C_BYTE,f
return
;; ------------------
i2c_recv_byte
clrf I2C_BYTE
movlw .8
movwf I2C_BIT_CNT
bsf STATUS,RP0
bsf I2C_SDA
i2c_recv_byte_loop
bsf I2C_SCL
bcf STATUS,RP0
btfsc I2C_SDA
bsf I2C_BYTE,0
bsf STATUS,RP0
bcf I2C_SCL
decfsz I2C_BIT_CNT,f
goto i2c_recv_byte_next
bcf I2C_SDA
bcf STATUS,RP0
return
i2c_recv_byte_next
bcf STATUS,C
rlf I2C_BYTE,f
goto i2c_recv_byte_loop
;; ------------------
i2c_ack
bsf STATUS,RP0
bcf I2C_SDA
bsf I2C_SCL
nop
nop
bcf I2C_SCL
bcf STATUS,RP0
return
;; ------------------
i2c_nack
bsf STATUS,RP0
bsf I2C_SDA
bsf I2C_SCL
nop
nop
bcf I2C_SCL
bcf I2C_SDA
bcf STATUS,RP0
return
;; -------------------------------------
|
