1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
|
;;
;; spreadspace pic utils
;;
;;
;; Copyright (C) 2011 Christian Pointner <equinox@spreadspace.org>
;;
;; This file is part of spreadspace pic utils.
;;
;; spreadspace pic utils is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; any later version.
;;
;; spreadspace pic utils is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with spreadspace pic utils. If not, see <http://www.gnu.org/licenses/>.
;;
;; -------------------------------------
;; PREAMBLE
LIST p=16F1847
include "p16f1847.inc"
__config _CONFIG1, _FOSC_INTOSC & _WDTE_OFF & _PWRTE_OFF & _MCLRE_ON & _CP_OFF & _CPD_OFF & _BOREN_OFF & _CLKOUTEN_OFF & _IESO_OFF & _FCMEN_OFF
__config _CONFIG2, _WRT_OFF & _PLLEN_OFF & _STVREN_OFF & _BORV_LO & _LVP_OFF
;; -------------------------------------
;; DEFINES
;; constants
BUF_STARTH EQU 020h
BUF_STARTL EQU 000h
BUF_ENDH EQU 023h
BUF_ENDL EQU 0BFh
;; I/O Pins
;; PortA
#define C1m PORTA,0
#define C2p PORTA,1
#define AMP_OUT PORTA,2
#define ADC_IN PORTA,3
#define SPEAKER PORTA,4
#define DBG1 PORTA,6
#define DBG2 PORTA,7
;; PortB
#define DBG0 PORTB,0
#define SDI PORTB,1
#define SDO PORTB,2
#define INT PORTB,3
#define SCK PORTB,4
#define CS PORTB,5
#define FILTER_EN PORTB,7
;; variables
;; all Pages
CNT0 EQU H'0070'
CNT1 EQU H'0071'
CNT2 EQU H'0072'
TMP EQU H'0073'
FLAGS EQU H'007F'
;; bits
;; FLAGS
UNDERRUN EQU .0
OVERRUN EQU .1
;; -------------------------------------
;; OFFSET
org .0
goto init
;; -------------------------------------
;; Interrupts
org .4
movlb b'00000000'
btfsc PIR1,TMR2IF
goto int_tmr2
btfsc PIR1,SSP1IF
goto int_spi
retfie
int_tmr2
bcf PIR1,TMR2IF
movlb b'00000001'
bsf ADCON0,GO
call wbuf_next
btfsc FLAGS,OVERRUN
retfie
int_tmr2_adcon
btfsc ADCON0,GO
goto int_tmr2_adcon
movf ADRESH,w
movwf INDF0
retfie
int_spi
bcf PIR1,SSP1IF
movlb b'00000100'
movf SSP1BUF,w
incf TMP,f
movf TMP,w
movwf SSP1BUF
movlb b'00000000'
retfie
;; -------------------------------------
;; SUBROUTINES
wbuf_reset
movlw BUF_STARTH
movwf FSR0H
movlw BUF_STARTL
movwf FSR0L
bcf FLAGS,OVERRUN
return
;; -------------------
wbuf_next
btfsc FLAGS,UNDERRUN
goto wbuf_move_ptr
movf FSR1H,w
xorwf FSR0H,w
btfss STATUS,Z
goto wbuf_move_ptr
movf FSR1L,w
xorwf FSR0L,w
btfss STATUS,Z
goto wbuf_move_ptr
bsf FLAGS,OVERRUN
return
wbuf_move_ptr
bcf FLAGS,UNDERRUN
addfsr FSR0,1
movf FSR0H,w
sublw BUF_ENDH
btfss STATUS,C
goto wbuf_wraparound
btfss STATUS,Z
return
movf FSR0L,w
sublw BUF_ENDL
btfsc STATUS,C
return
wbuf_wraparound
movlw BUF_STARTH
movwf FSR0H
movlw BUF_STARTL
movwf FSR0L
return
;; -------------------
rbuf_reset
movlw BUF_STARTH
movwf FSR1H
movlw BUF_STARTL
movwf FSR1L
bsf FLAGS,UNDERRUN
;; -------------------
rbuf_next
btfsc FLAGS,OVERRUN
goto rbuf_move_ptr
movf FSR0H,w
xorwf FSR1H,w
btfss STATUS,Z
goto rbuf_move_ptr
movf FSR0L,w
xorwf FSR1L,w
btfss STATUS,Z
goto rbuf_move_ptr
bsf FLAGS,UNDERRUN
return
rbuf_move_ptr
bcf FLAGS,OVERRUN
addfsr FSR1,1
movf FSR1H,w
sublw BUF_ENDH
btfss STATUS,C
goto rbuf_wraparound
btfss STATUS,Z
return
movf FSR1L,w
sublw BUF_ENDL
btfsc STATUS,C
return
rbuf_wraparound
movlw BUF_STARTH
movwf FSR1H
movlw BUF_STARTL
movwf FSR1L
return
;; -------------------------------------
;; INIT
init
;; BANK 4
movlb b'00000100'
movlw b'01000000'
movwf SSP1STAT
movlw b'00010000'
movwf SSP1CON3
movlw b'00100100'
movwf SSP1CON1
;; BANK 3
movlb b'00000011'
movlw b'00001111' ; PORTA0:3 analog, PORTA4:7, digital
movwf ANSELA ; PORTB0:7 digital
clrf ANSELB
;; BANK 2
movlb b'00000010'
;; BANK 1
movlb b'00000001'
movlw b'00101111'
movwf TRISA
movlw b'01110010'
movwf TRISB
; movlw b'01011000' ; 1 MHz
; movlw b'01100000' ; 2 MHz
; movlw b'01101000' ; 4 MHz
; movlw b'01110000' ; 8 MHz
movlw b'01111000' ; 16 MHz
movwf OSCCON
movlw b'01010000' ; Left Justified, FOSC/16, NEG=VSS,POS=VDD
movwf ADCON1
movlw b'00001101' ; AN3, ADC On
movwf ADCON0
movlw b'00001010' ; SSPIE,TMR2IE
movwf PIE1
;; BANK 0
movlb b'00000000'
movlw .124 ; 8 kHz @ 16MHz
movwf PR2
clrf TMR2 ; reset TMR2
movlw b'00000101' ; Postscaler 1:1,Timer On,Prescaler 1:4
movwf T2CON
clrf PIR1 ; reset all used interupt flags
movlw b'11000000' ; GIE,PEIE
movwf INTCON
bcf FILTER_EN
bsf INT
bcf DBG0
bcf DBG1
bcf DBG2
;; -------------------------------------
;; MAINLOOP
main
;; movlw .255
;; movwf CNT0
;; outer1
;; movlw .255
;; movwf CNT1
;; outer
;; movlw .5
;; movwf CNT2
;; inner
;; decfsz CNT2,f
;; goto inner
;; decfsz CNT1,f
;; goto outer
;; decfsz CNT0,f
;; goto outer1
;; movlw b'00001000'
;; xorwf PORTB,f
goto main
;; -------------------------------------
;; END
end
|
