1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
|
;;
;; spreadspace pic utils
;;
;;
;; Copyright (C) 2011 Christian Pointner <equinox@spreadspace.org>
;;
;; This file is part of spreadspace pic utils.
;;
;; spreadspace pic utils is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; any later version.
;;
;; spreadspace pic utils is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with spreadspace pic utils. If not, see <http://www.gnu.org/licenses/>.
;;
;; -------------------------------------
;; PREAMBLE
LIST p=16F887
include "p16f887.inc"
__config _CONFIG1, _DEBUG_OFF & _LVP_OFF & _FCMEN_OFF & _IESO_OFF & _BOR_OFF & _CPD_OFF & _CP_OFF & _MCLRE_OFF & _PWRTE_OFF & _WDT_OFF & _INTOSC
__config _CONFIG2, _BOR21V & _WRT_256
;; -------------------------------------
;; DEFINES (chip/com specific)
#define BOOTPIN PORTC,7
USERVECT EQU H'100'
ISRVECT EQU USERVECT + H'4'
FLASH_BOUNDARY EQU b'00001111' ; flash write boundary is at 16 bytes boundaries
VERSION_MAJ EQU .0
VERSION_MIN EQU .1
NAME_0 EQU 'n'
NAME_1 EQU 'i'
NAME_2 EQU 'l'
DEVID_L EQU H'82'
DEVID_H EQU H'20'
FLASH_SIZE_L EQU H'00'
FLASH_SIZE_H EQU H'20' ; 0x2000 -> 8192 Words of Flash
FSS EQU .16 ; writing is done 8 words at a time but 16 words get erased
EEPROM_SIZE_L EQU H'00'
EEPROM_SIZE_H EQU H'01' ; 0x0100 -> 256 Bytes of EEPROM
MESS EQU .64 ; this limit is because of to combuff size and single byte len field for messages
SUPPORTED_H EQU .0
SUPPORTED_L EQU b'00000110' ; only read/write flash is supported by now
#define HOOK_CMD_RESET cmd_not_impl
#define HOOK_CMD_R_FLASH cmd_r_flash
#define HOOK_CMD_W_FLASH cmd_w_flash
#define HOOK_CMD_R_EEPROM cmd_not_impl
#define HOOK_CMD_W_EEPROM cmd_not_impl
#define HOOK_CMD_R_CONFIG cmd_not_impl
#define HOOK_CMD_W_CONFIG cmd_not_impl
;; Variables
combuff EQU H'0020'
combuff_end EQU H'006F'
current_cmdlen EQU H'0070'
csum EQU H'0071'
flags EQU H'007D'
#define F_CMD_STARTED flags,0
cnt2 EQU H'007E'
cnt EQU H'007F'
;; -------------------------------------
;; DEFINES (defines)
;; ERROR codes
E_OK EQU .0
E_INV_CMD EQU .1
E_BAD_CSUM EQU .2
E_NOT_IMPL EQU .3
E_FLASH_WERR EQU .4
E_ADDR_INVALID EQU .5
E_ADDR_PROHIB EQU .6
E_VALUE_OOB EQU .7
;; CMD codes
CMD_INVALID EQU .0
CMD_IDENTIFY EQU .1
CMD_BOOT EQU .2
CMD_RESET EQU .3
CMD_R_FLASH EQU .4
CMD_W_FLASH EQU .5
CMD_R_EEPROM EQU .6
CMD_W_EEPROM EQU .7
CMD_R_CONFIG EQU .8
CMD_W_CONFIG EQU .9
CMD_MAX EQU .9
CMD_MIN_LEN EQU .3
;; -------------------------------------
;; Boot test
org .0
;; btfsc BOOTPIN
;; goto USERVECT
goto com_init
;; -------------------------------------
;; goto user ISR
org .4
isr
goto ISRVECT
;; -------------------------------------
;; Bootloader (Generic Subroutines)
send_answer ; generic answer message, leave len of data in W
addlw .3
movwf combuff + .1
decf combuff + .1,w
movwf cnt
movlw combuff
movwf FSR
clrf csum
send_answer_next
movf INDF,w
call com_tx_byte
incf FSR,f
decfsz cnt,f
goto send_answer_next
movf csum,w
call com_tx_byte
return
;; ------------------
ack_cmd ; short answers which only contain return code
movwf combuff + .2
movlw .1
call send_answer
return
;; -------------------------------------
;; Bootloader (com specific subroutines and init)
;; ------------------
com_tx_byte ;send one byte and add it to csum
btfss PIR1,TXIF
goto com_tx_byte
movwf TXREG
xorwf csum,f
return
;; ------------------
com_rx_byte
btfsc RCSTA,OERR
goto uart_rx_oe
btfss PIR1,RCIF
goto com_rx_byte
btfsc RCSTA,FERR
goto uart_rx_fe
movf RCREG,w
return
uart_rx_oe ; recover from overflow
bcf RCSTA,CREN
bsf RCSTA,CREN
goto com_rx_byte
uart_rx_fe ; recover from framing error
movf RCREG,w
goto com_rx_byte
;; ------------------
com_init
;; bank 3
bsf STATUS,RP0
bsf STATUS,RP1
movlw b'00001000' ; TX non-inverted, 16bit Baudrate, no auto baud detect
;; movlw b'00011000' ; TX inverted, 16bit Baudrate, no auto baud detect
movwf BAUDCTL
;; bank 1
bcf STATUS,RP1
movlw b'01110000' ; set internal OSC to 8MHz
movwf OSCCON
movlw b'00100100' ; Baudrate = High Speed, async mode, transmit enabled, 8bit
movwf TXSTA
movlw .34 ; Baudrate = 57600 (@ 8MHz) -> -0,79 % Error
;; movlw .51 ; Baudrate = 38400 (@ 8MHz) -> -0,002 % Error
;; movlw .103 ; Baudrate = 19200 (@ 8MHz) -> 0,16 % Error
movwf SPBRG
clrf SPBRGH
;; bank 0
bcf STATUS,RP0
movlw b'10010000' ; enable Serial Port, 8bit, enable continues receive, disable address detection
movwf RCSTA
;; -------------------------------------
;; Bootloader (generic init)
wait_new_cmd
movlw combuff
movwf FSR
clrf combuff
clrf current_cmdlen
clrf flags
wait_cmd
call com_rx_byte
movwf INDF ; process received byte
incf FSR,f
btfss F_CMD_STARTED
goto wait_cmd_len
movf current_cmdlen,f
btfsc STATUS,Z
goto new_cmd
decfsz current_cmdlen,f
goto wait_cmd
goto exec_cmd
wait_cmd_len ; command code received, now wait for length
bsf F_CMD_STARTED
goto wait_cmd
new_cmd ; got new command code and length -> check it
movf combuff,w
sublw CMD_MAX
btfss STATUS,C
goto invalid_cmd
movlw CMD_MIN_LEN ; check for minimum command len
subwf combuff + .1,w
btfss STATUS,C
goto invalid_cmd
movlw .2 ; 2 bytes already received
subwf combuff + .1,w
movwf current_cmdlen
goto wait_cmd
exec_cmd ; command is complete -> check csum
movlw combuff
movwf FSR
movf combuff + .1,w
movwf cnt
clrf csum
exec_cmd_check_csum
movf INDF,w
xorwf csum,f
incf FSR,f
decfsz cnt,f
goto exec_cmd_check_csum
movf csum,f
btfss STATUS,Z
goto csum_error
movf combuff,w ; command is correct and complete -> dispatch
addwf PCL,f
goto wait_new_cmd
goto cmd_identify ; identify
goto cmd_boot ; boot
goto HOOK_CMD_RESET ; reset
goto HOOK_CMD_R_FLASH ; read flash segment
goto HOOK_CMD_W_FLASH ; write flash segment
goto HOOK_CMD_R_EEPROM ; read eeprom
goto HOOK_CMD_W_EEPROM ; write eeprom
goto HOOK_CMD_R_CONFIG ; read config
goto HOOK_CMD_R_CONFIG ; write config
;; ** generic error messages *******
invalid_cmd ; received command code is not known or len is bogus
movlw E_INV_CMD
call ack_cmd
goto wait_new_cmd
csum_error ; received command has an invalid check sum
movlw E_BAD_CSUM
call ack_cmd
goto wait_new_cmd
address_invalid ; received command uses invalid address (i.e. not aligned to 16bytes)
movlw E_ADDR_INVALID
call ack_cmd
goto wait_new_cmd
address_prohibited ; received command uses prohibited address (i.e. FLASH < 0x100)
movlw E_ADDR_PROHIB
call ack_cmd
goto wait_new_cmd
;; ** generic command handlers ************
;; ** identify *******
cmd_identify
clrf csum
movf combuff,w
call com_tx_byte
movlw .19
call com_tx_byte
movlw E_OK
call com_tx_byte
movlw VERSION_MIN
call com_tx_byte
movlw VERSION_MAJ
call com_tx_byte
movlw NAME_0
call com_tx_byte
movlw NAME_1
call com_tx_byte
movlw NAME_2
call com_tx_byte
movlw DEVID_L
call com_tx_byte
movlw DEVID_H
call com_tx_byte
movlw FLASH_SIZE_L
call com_tx_byte
movlw FLASH_SIZE_H
call com_tx_byte
movlw FSS
call com_tx_byte
movlw EEPROM_SIZE_L
call com_tx_byte
movlw EEPROM_SIZE_H
call com_tx_byte
movlw MESS
call com_tx_byte
movlw SUPPORTED_L
call com_tx_byte
movlw SUPPORTED_H
call com_tx_byte
movf csum,w
call com_tx_byte
goto wait_new_cmd
;; ** boot *******
cmd_boot
movlw E_OK
call ack_cmd
goto USERVECT
;; ** not implemented commands *******
cmd_not_impl
movlw E_NOT_IMPL
call ack_cmd
goto wait_new_cmd
;; -------------------------------------
;; chip specific commands
#include "cmds-16f887.inc"
;; -------------------------------------
;; -------------------------------------
;; dummy user code
org USERVECT
;; goto USERVECT
bsf STATUS,RP0
bcf TRISD,0
bcf STATUS,RP0
userloop
movlw b'00000001'
xorwf PORTD,f
movlw .255
movwf cnt
usercnt
movlw .255
movwf cnt2
usercnt2
decfsz cnt2,f
goto usercnt2
decfsz cnt,f
goto usercnt
goto userloop
;; -------------------------------------
;; END
end
|
