summaryrefslogtreecommitdiff
path: root/bootloader/com-16f887-uart.inc
blob: fb4575eff98ffe52f3a20cf17f2ae228b1519014 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
  ;;
  ;;  spreadspace pic utils
  ;;
  ;;
  ;;  Copyright (C) 2011-2013 Christian Pointner <equinox@spreadspace.org>
  ;;
  ;;  This file is part of spreadspace pic utils.
  ;;
  ;;  spreadspace pic utils is free software: you can redistribute it and/or modify
  ;;  it under the terms of the GNU General Public License as published by
  ;;  the Free Software Foundation, either version 3 of the License, or
  ;;  any later version.
  ;;
  ;;  spreadspace pic utils is distributed in the hope that it will be useful,
  ;;  but WITHOUT ANY WARRANTY; without even the implied warranty of
  ;;  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  ;;  GNU General Public License for more details.
  ;;
  ;;  You should have received a copy of the GNU General Public License
  ;;  along with spreadspace pic utils. If not, see <http://www.gnu.org/licenses/>.
  ;;

  ;; --- transmit byte and add it to csum
com_tx_byte
  btfss     PIR1,TXIF
  goto      com_tx_byte
  movwf     TXREG
  xorwf     csum,f
  return

  ;; ---- wait for byte to be received
com_rx_byte
  btfsc     RCSTA,OERR
  goto      uart_rx_oe
  btfss     PIR1,RCIF
  goto      com_rx_byte
  btfsc     RCSTA,FERR
  goto      uart_rx_fe
  movf      RCREG,w
  return

uart_rx_oe                ; recover from overflow
  bcf       RCSTA,CREN
  bsf       RCSTA,CREN
  goto      com_rx_byte

uart_rx_fe                ; recover from framing error
  movf      RCREG,w
  goto      com_rx_byte

  ;; ----- initialize com (not a subroutine, com_init is called by generic_init
com_init
  ;; bank 3
  bsf       STATUS,RP0
  bsf       STATUS,RP1
  movlw     b'00001000'   ; TX non-inverted, 16bit Baudrate, no auto baud detect
  ;; movlw     b'00011000'   ; TX inverted, 16bit Baudrate, no auto baud detect
  movwf     BAUDCTL

  ;; bank 1
  bcf       STATUS,RP1
  movlw     b'01110000'   ; set internal OSC to 8MHz
  movwf     OSCCON
  movlw     b'00100100'   ; Baudrate = High Speed, async mode, transmit enabled, 8bit
  movwf     TXSTA
  movlw     .34           ; Baudrate = 57600 (@ 8MHz) -> -0,79 % Error
  ;; movlw     .51           ; Baudrate = 38400 (@ 8MHz) -> -0,002 % Error
  ;; movlw     .103          ; Baudrate = 19200 (@ 8MHz) ->  0,16 % Error
  movwf     SPBRG
  clrf      SPBRGH

  ;; bank 0
  bcf       STATUS,RP0
  movlw     b'10010000'   ; enable Serial Port, 8bit, enable continues receive, disable address detection
  movwf     RCSTA